Zsh

2016-02-24T09:53:34Z

Justgerrardz:

[[Category:コマンドシェル]]
[[cs:Zsh]]
[[de:Zsh]]
[[en:Zsh]]
[[es:Zsh]]
[[fr:Zsh]]
[[ru:Zsh]]
[[zh-CN:Zsh]]
[http://www.zsh.org Zsh] は対話式シェルとしてもスクリプト言語のインタプリタとしても使えるパワフルなシェルです。[[Bash]] と互換性がありながら (デフォルトではありません、{{ic|emulate sh}} を実行した時だけです)、Zsh には多くの利点があります:

* 高速
* 高度なタブ補完
* 高度なグロブ
* 高度な行列処理
* 完全にカスタマイズ可能

Zsh FAQ には他にも Zsh をあなたのシェルとして使うべき [http://zsh.sourceforge.net/FAQ/zshfaq01.html#l4 理由] が列挙されています。

== インストール ==

インストールをする前に現在使っているシェルが何なのか知っておくとよいでしょう:

$ echo $SHELL

[[公式リポジトリ]]にある {{Pkg|zsh}} パッケージを[[pacman|インストール]]してください。追加の補完定義を使いたい場合は、{{pkg|zsh-completions}} パッケージもインストールします。

=== 初期設定 ===

ターミナルで次のコマンドを実行して Zsh が正しくインストールされたか確認してください:

$ zsh

基本的な設定を説明する '''zsh-newuser-install''' が表示されるはずです。これをスキップしたい場合、{{ic|q}} を押して下さい。手動で呼び出すには:

$ zsh /usr/share/zsh/functions/Newuser/zsh-newuser-install -f

=== Zsh をデフォルトのシェルにする ===

シェルが {{ic|/etc/shells}} に記載されていれば、{{ic|chsh}} コマンドを使って root 権限なしでデフォルトシェルを変更することができます。[[公式リポジトリ]]から Zsh をインストールしたのなら、既に {{ic|/etc/shells}} にエントリが作られているはずです。

現在使っているユーザーのデフォルトシェルを変更するには:

$ chsh -s $(which zsh)

{{Note|Zsh をデフォルトシェルとして起動するには、一度ログアウトしてからログインしなおす必要があります。}}

最ログイン後、Bash とは見た目が異なる Zsh のプロンプトが表示されていることに気づくでしょう。また、次のコマンドを実行することで Zsh が現在のシェルになっていることを確認できます:

$ echo $SHELL

{{Tip|{{Pkg|bash}} を置き換える場合、{{ic|~/.bashrc}} から {{ic|~/.zshrc}} に (例: プロンプトと[[Bash#エイリアス|エイリアス]]) また {{ic|~/.bash_profile}} から {{ic|~/.zprofile}} に (例: [[ログイン時に X を起動|X Window System を起動するコード]]) にコードを移動するとよいでしょう。}}

== 設定ファイル ==

ログイン時、Zsh は以下のファイルをこの順番で読み込みます:
;{{ic|/etc/zsh/zshenv}}:このファイルにはグローバルな[[#$PATH の設定|コマンド検索パス]]やシステム共通の[[環境変数]]を設定するコマンドを記述します。出力を発生させるコマンドや tty に基づいているコマンドを含めてはいけません。
;{{ic|~/.zshenv}}:このファイルには[[#$PATH の設定|コマンドの検索パス]]を設定するコマンドや、重要な環境変数を含めます; 出力をするコマンドや tty に基づいているコマンドを含めてはいけません。
;{{ic|/etc/zsh/zprofile}}:グローバルな設定ファイルであり、ログイン時に読み込まれます。ログイン時に毎回実行するコマンドを記述するのに使われます。Arch Linux では、初めから {{ic|/etc/profile}} を source する[https://projects.archlinux.org/svntogit/packages.git/tree/trunk/zprofile?h=packages/zsh 一行]が入っています。詳しくは[[#全ユーザー共通の設定ファイル|下]]を参照。
;{{ic|/etc/profile}}:このファイルはログイン時に Bourne 互換シェルによって読み込まれます: ログイン時やアプリケーション固有の設定 {{ic|/etc/profile.d/*.sh}}) を設定します。
;{{ic|~/.zprofile}}:このファイルは一般的にユーザーのスクリプトを自動で実行するために使われます。
;{{ic|/etc/zsh/zshrc}}:グローバルな設定ファイルであり、インタラクティブシェルとして起動した場合に読み込まれます。
;{{ic|~/.zshrc}}:これは Zsh のメインの設定ファイルです。
;{{ic|/etc/zsh/zlogin}}:グローバルな設定ファイルであり、ログインシェルとして起動した場合に、初期化の最後に読み込まれます。
;{{ic|~/.zlogin}}:{{ic|/etc/zsh/zlogin}} と同じ設定ファイルですが、ユーザーごとの設定を記述するところが違います。
;{{ic|/etc/zsh/zlogout}}:グローバルな設定ファイルであり、ログインシェルが終了するときに読み込まれます。
;{{ic|~/.zlogout}}:{{ic|/etc/zsh/zlogout}} と同じ設定ファイルですが、ユーザーごとの設定を記述するところが違います。

{{Note|
* Arch の {{Pkg|zsh}} パッケージで使われているパスは [[man ページ]]で使われているデフォルトのパスとは異なっています。
* {{ic|$ZDOTDIR}} のデフォルトは {{ic|$HOME}} です。
* {{ic|/etc/profile}} は Zsh のスタートアップファイルの標準リストに含まれていませんが、{{Pkg|zsh}} パッケージに入っている {{ic|/etc/zsh/zprofile}} から読み込まれます。{{ic|/etc/profile}} で {{ic|$PATH}} 変数を設定すると {{ic|~/.zshenv}} に設定した {{ic|$PATH}} 変数を全て上書きしてしまうので注意してください。これを防ぐには、{{ic|/etc/zsh/zprofile}} をあなたの作ったファイルに置き換えるか、{{ic|~/.zshrc}} から {{ic|$PATH}} 変数を設定してください。
}}

=== 全ユーザー共通の設定ファイル ===

場合によっては Zsh ユーザー全てに設定を適用させたいときもあると思われます。zsh(1) によれば {{ic|/etc/zshrc}} などグローバルな設定ファイルはいくつか存在します。ただし、これは Arch では少し事情が異なっており、代わりに {{ic|/etc/zsh/}} を使うようにコンパイルされています [https://projects.archlinux.org/svntogit/packages.git/tree/trunk/PKGBUILD?h=packages/zsh#n34]。

従って、ユーザー共通の設定をしたいときは {{ic|/etc/zshrc}} ではなく {{ic|/etc/zsh/zshrc}} を使って下さい。これは {{ic|/etc/zsh/zshenv}}, {{ic|/etc/zsh/zlogin}}, {{ic|/etc/zsh/zlogout}} でも同じです。これらのファイルはデフォルトではインストールされないので、必要なときに作成してください。

唯一の例外は {{ic|zprofile}} で、これは {{ic|/etc/profile}} を使います。

== ~/.zshrc の設定 ==

Zsh は何も設定しなくても使うことができますが、あなたが使いたい機能はほとんど設定されていないでしょう。ただし Zsh で利用できるカスタム化の道は険しく、Zsh の設定は困難をきわめ多くの時間を浪費するかもしれません。

=== シンプルな .zshrc ===

下にはサンプルの設定ファイルが含まれており、Zsh のカスタマイズの方法の例だけでなくデフォルトオプションのセットも提供しています。この設定を使うには {{ic|.zshrc}} という名前でファイルを保存してください。ログインしなおさなくても次を実行することで変更を適用できます:

$ source ~/.zshrc

以下はシンプルな {{ic|.zshrc}} です、基点としてはピッタリでしょう:

{{hc|~/.zshrc|
autoload -U compinit promptinit
compinit
promptinit

# This will set the default prompt to the walters theme
prompt walters}}

=== $PATH の設定 ===

zsh でユーザーごとにシステムパスを設定する方法についての情報はここにあります: http://zsh.sourceforge.net/Guide/zshguide02.html#l24

以下を {{ic|~/.zshenv}} に追加してください:
{{hc|~/.zshenv|
typeset -U path
path=(~/bin /other/things/in/path $path[@])}}

=== コマンド補完 ===

Zsh の一番魅力的な機能はおそらく先進的な自動補完機能でしょう。少なくとも、{{ic|.zshrc}} で自動補完を有効にしたいと思うはずです。自動補完を有効にするには、以下を追加してください:

{{hc|~/.zshrc|
autoload -U compinit
compinit}}

この設定は ssh/scp/sftp のホスト名の補完も含んでいますが、この機能を動かすには {{ic|~/.ssh/known_hosts}} で ssh がホスト名をハッシュ化しないようにする必要があります。
{{Warning|ハッシュ化を解除すると [http://blog.rootshell.be/2010/11/03/bruteforcing-ssh-known_hosts-files/ "Island-hopping" 攻撃] に無防備になります。そのことを前もって知った上で、次の行をコメントアウトするか値を {{ıc|no}} に設定してください:
{{hc|/etc/ssh/ssh_config|
#HashKnownHosts yes}}
これで {{ic|~/.ssh/known_hosts}} をどこか他のところに移動すれば ssh はハッシュ化されてないホスト名を使って新しいファイルを作成します (以前のホストは消失します)。詳細については、[http://nms.lcs.mit.edu/projects/ssh/README.hashed-hosts hashed-hosts] に関する SSH の readme を見て下さい。
}}

矢印キーのインターフェイスを使って自動補完するには、以下を追加して下さい:
{{hc|~/.zshrc|
zstyle ':completion:*' menu select}}
:''メニューを有効にするには、タブを二度押して下さい。''

エイリアスでコマンドラインの自動補完を切り替えるには、以下を追加して下さい:
{{hc|~/.zshrc|
setopt completealiases}}

=== "command not found" フック ===

[[Pkgfile#.22Command_not_found.22_フック|Pkgfile/"Command not found" フック]] を見て下さい。

=== 履歴に同じ行が重複するのを避ける ===

履歴の重複する行を無視するには、以下を追加して下さい:
{{hc|~/.zshrc|
setopt HIST_IGNORE_DUPS}}

既に作成された重複を履歴から取り除くには、次を実行:
$ sort -t ";" -k 2 -u ~/.zsh_history | sort -o ~/.zsh_history

=== ttyctl コマンド ===

[http://zsh.sourceforge.net/Doc/Release/Shell-Builtin-Commands.html#index-tty_002c-freezing] には Zsh の {{ic|ttyctl}} コマンドの説明があります。{{ic|ttyctl}} を使うことでターミナルを "freeze/unfreeze" することができます。ターミナルの状態を変更するプログラムは多数存在しますが、終了時にターミナルの設定を元に戻さないことがあります。手動でターミナルをリセットしなくてもいいようにするには、以下を使います:

{{hc|~/.zshrc|
ttyctl -f}}

=== キーバインド ===

Zsh は readline を使っていません、代わりに自身のパワフルな zle を使っています。zle は {{ic|/etc/inputrc}} や {{ic|~/.inputrc}} を読みません。
zle には [[emacs]] モードと [[vi]] モードがあります。デフォルトでは、{{ic|$EDITOR}} 環境変数から emacs と vi どちらのキーをあなたが使いたいのか考えます。この変数が空の場合、デフォルトは emacs モードです。 {{ic|bindkey -v}} や {{ic|bindkey -e}} でモードを変更することが可能です。

特殊なキーを動作させるには:
{{hc|~/.zshrc|2=
# create a zkbd compatible hash;
# to add other keys to this hash, see: man 5 terminfo
typeset -A key

key[Home]=${terminfo[khome]}

key[End]=${terminfo[kend]}
key[Insert]=${terminfo[kich1]}
key[Delete]=${terminfo[kdch1]}
key[Up]=${terminfo[kcuu1]}
key[Down]=${terminfo[kcud1]}
key[Left]=${terminfo[kcub1]}
key[Right]=${terminfo[kcuf1]}
key[PageUp]=${terminfo[kpp]}
key[PageDown]=${terminfo[knp]}

# setup key accordingly
[[ -n "${key[Home]}" ]] && bindkey "${key[Home]}" beginning-of-line
[[ -n "${key[End]}" ]] && bindkey "${key[End]}" end-of-line
[[ -n "${key[Insert]}" ]] && bindkey "${key[Insert]}" overwrite-mode
[[ -n "${key[Delete]}" ]] && bindkey "${key[Delete]}" delete-char
[[ -n "${key[Up]}" ]] && bindkey "${key[Up]}" up-line-or-history
[[ -n "${key[Down]}" ]] && bindkey "${key[Down]}" down-line-or-history
[[ -n "${key[Left]}" ]] && bindkey "${key[Left]}" backward-char
[[ -n "${key[Right]}" ]] && bindkey "${key[Right]}" forward-char
[[ -n "${key[PageUp]}" ]] && bindkey "${key[PageUp]}" beginning-of-buffer-or-history
[[ -n "${key[PageDown]}" ]] && bindkey "${key[PageDown]}" end-of-buffer-or-history

# Finally, make sure the terminal is in application mode, when zle is
# active. Only then are the values from $terminfo valid.
if (( ${+terminfo[smkx]} )) && (( ${+terminfo[rmkx]} )); then
function zle-line-init () {
printf '%s' "${terminfo[smkx]}"
}
function zle-line-finish () {
printf '%s' "${terminfo[rmkx]}"
}
zle -N zle-line-init
zle -N zle-line-finish
fi
}}

{{Note|To get the proper sequences for certain key combinations, start {{ic|cat}} or {{ic|read}} without any parameters and press them; they should then be printed in the terminal. Both can be closed again via {{ic|Ctrl+c}}.}}

==== terminfo を使わない方法 ====

{{ic|autoload zkbd}} を実行してから {{ic|zkbd}} を実行して下さい。キーを押せない場合は (例: {{ic|F11}} はウィンドウを最大化します)、スペースを押してスキップして下さい。zkbd が完了した後、以下を {{ic|~/.zshrc}} に追加して下さい:

{{hc|~/.zshrc|autoload zkbd
source ~/.zkbd/$TERM-:0.0 # may be different - check where zkbd saved yours

[[ -n ${key[Backspace]} ]] && bindkey "${key[Backspace]}" backward-delete-char
[[ -n ${key[Insert]} ]] && bindkey "${key[Insert]}" overwrite-mode
[[ -n ${key[Home]} ]] && bindkey "${key[Home]}" beginning-of-line
[[ -n ${key[PageUp]} ]] && bindkey "${key[PageUp]}" up-line-or-history
[[ -n ${key[Delete]} ]] && bindkey "${key[Delete]}" delete-char
[[ -n ${key[End]} ]] && bindkey "${key[End]}" end-of-line
[[ -n ${key[PageDown]} ]] && bindkey "${key[PageDown]}" down-line-or-history
[[ -n ${key[Up]} ]] && bindkey "${key[Up]}" up-line-or-search
[[ -n ${key[Left]} ]] && bindkey "${key[Left]}" backward-char
[[ -n ${key[Down]} ]] && bindkey "${key[Down]}" down-line-or-search
[[ -n ${key[Right]} ]] && bindkey "${key[Right]}" forward-char
}}

==== ncurses アプリケーションのキーバインド ====

ncurses アプリケーションをキーストロークにバインドすることが可能ですが、対話はできません。{{ic|BUFFER}} 変数を使って動作させて下さい。以下の例は {{ic|Alt+\}} で ncmpcpp を開きます:
{{hc|~/.zshrc|2=
ncmpcppShow() { BUFFER="ncmpcpp"; zle accept-line; }
zle -N ncmpcppShow
bindkey '^[\' ncmpcppShow
}}

=== 履歴検索 ===

以下の行を .zshrc に追加して下さい:

{{hc|~/.zshrc|<nowiki>
[[ -n "${key[PageUp]}" ]] && bindkey "${key[PageUp]}" history-beginning-search-backward
[[ -n "${key[PageDown]}" ]] && bindkey "${key[PageDown]}" history-beginning-search-forward
</nowiki>}}

これを設定すると、現在の入力で始まる過去のコマンドだけが表示されるようになります。

=== プロンプト ===

Zsh には手軽にカラープロンプトを設定する方法があります。{{ic|.zshrc}} でプロンプトが自動ロードされるように設定してください。以下の行を追加することで自動ロードされます:

{{hc|~/.zshrc|
autoload -U promptinit
promptinit
}}

次のコマンドを実行することで利用可能なプロンプトを見ることができます:

$ prompt -l

表示されたコマンドの一つを試すには、prompt コマンドの後に使いたいプロンプトの名前を加えて下さい。例えば、{{ic|walters}} プロンプトを使うには、次のように入力します:

$ prompt walters

全ての利用可能なテーマをプレビューするには次のコマンドを使って下さい:

$ prompt -p

=== プロンプトのカスタマイズ ===

上述のプロンプトに満足がいかない（もしくはプロンプトを拡張したい）場合、Zsh にはカスタムプロンプトを作る機能が備わっています。全てのシェルに共通な左側だけのプロンプトに加え、Zsh は左右両側を使うプロンプトをサポートしています。{{ic|1=PROMPT=}} と以下の変数を使うことでプロンプトをカスタマイズできます:

==== プロンプト変数 ====

{| class="wikitable"
! scope="col" width="10%"| コマンド || !scope="col" width="60%"|説明 || !scope="col" width="30%"|コメント
|-
! colspan="3" | 一般
|-
|{{ic|%n}} || ユーザー名
|-
|{{ic|%m}} || コンピュータのホスト名 (ドットの前の部分まで)
|-
|{{ic|%M}} || コンピュータのホスト名
|-
|{{ic|%l}} || 現在の tty
|-
|{{ic|%?}} || 最後に実行したアプリケーションのリターンコード
|-
|{{ic|%#}} || ユーザー特権によるプロンプト (root なら {{ic|#}} その他なら {{ic|%}})
|-
! colspan="3" | 時間
|-
| {{ic|%T}}|| システム時刻 (HH:MM)
|-
| {{ic|%*}}|| システム時刻 (HH:MM:SS)
|-
| {{ic|%D}}|| システム日付 (YY-MM-DD)
|-
! colspan="3" | ディレクトリ
|-
| {{ic|%d}} || カレントディレクトリ。
| rowspan="2" | 数字を前に付けることでパスの一部だけを表示することが可能です。例えば {{ic|%1d}} と入力した場合、{{ic|/usr/bin}} にいるときは {{ic|bin}} と表示されます。負の値も使えます: {{ic|%-1d}} は上の例だと {{ic|/}} と表示されます。
|-
| {{ic|%~}}|| カレントディレクトリ。{{ic|$HOME}} やそのサブディレクトリにいる場合、{{ic|$HOME}} の部分は {{ic|~}} に置き換えられます。
|-
! colspan="3" | 整形
|-
| {{ic|%U [...] %u}} || 下線表示の始まりと終わり
|-
| {{ic|%B [...] %b}} || 太字表示の始まりと終わり
|-
| {{ic|<nowiki>%{ [...] %}</nowiki>}} || 表示されない領域。色の設定をするときに使います。このタグによって Zsh はタグの中にあるものを全て無視します。使用しないとプロンプトの縁やインデントに妙な影響が出ることがあります。
|-
! colspan="3" | カラー
|-
| {{ic|$fg[color]}}||文字色を設定します (red, green, blue など - 太字デフォルト)。
| rowspan="4" | Zsh は [[Bash カラープロンプト|Bash]] とは違ったふうに色を設定します。色を使うには {{ic|.zshrc}} で {{ic|1=PROMPT=}} の前に {{ic|autoload -U colors && colors}} を追加してください。通常、カーソルが動かないように色の設定は {{ic|%{ [...] %} }} の中に記述します。
|-
| {{ic|$fg_no_bold[color]}}|| 太字でない文字色を設定します。
|-
| {{ic|$fg_bold[color]}}|| 太字の文字色を設定します。
|-
| {{ic|$reset_color}}|| 文字色をデフォルトの色に戻します。
|}

{| class="wikitable"
|-
! colspan="2" | 利用できるカラー
|-
| {{ic|black}} または {{ic|0}} || {{ic|red}} または {{ic|1}}
|-
| {{ic|green}} または {{ic|2}} || {{ic|yellow}} または {{ic|3}}
|-
| {{ic|blue}} または {{ic|4}} || {{ic|magenta}} または {{ic|5}}
|-
| {{ic|cyan}} または {{ic|6}} || {{ic|white}} または {{ic|7}}
|}

{{Note|太字の文字色は通常の文字色と必ずしも同じ色になるわけではありません。例えば、{{ic|$fg['yellow']}} は褐色や濃黄のようになりますが、{{ic|$fg_bold['yellow']}} はやや明るい普通の黄色のようになります。}}

==== サンプル ====

以下のようにすることで左右両側にプロンプトを表示できます:
PROMPT="%{$fg[red]%}%n%{$reset_color%}@%{$fg[blue]%}%m %{$fg_no_bold[yellow]%}%1~ %{$reset_color%}%#"
RPROMPT="[%{$fg_no_bold[yellow]%}%?%{$reset_color%}]"

次のようになります (色は省略):
username@host ~ % [0]

=== ディレクトリスタック ===

Zsh を設定して DIRSTACKSIZE 最後に訪れたフォルダを覚えさせることが可能です。これにより素早く ''cd'' することができます。設定ファイルにいくつか設定を加える必要があります:

{{hc|.zshrc|<nowiki>
DIRSTACKFILE="$HOME/.cache/zsh/dirs"
if [[ -f $DIRSTACKFILE ]] && [[ $#dirstack -eq 0 ]]; then
dirstack=( ${(f)"$(< $DIRSTACKFILE)"} )
[[ -d $dirstack[1] ]] && cd $dirstack[1]
fi
chpwd() {
print -l $PWD ${(u)dirstack} >$DIRSTACKFILE
}

DIRSTACKSIZE=20

setopt autopushd pushdsilent pushdtohome

## Remove duplicate entries
setopt pushdignoredups

## This reverts the +/- operators.
setopt pushdminus
</nowiki>}}

次のコマンドでディレクトリスタックを表示できます:
dirs -v
{{ic|cd -<NUM>}} で訪問済みのフォルダに戻ります。ダッシュの後は自動補完が利用できます。自動補完メニューを使っている場合はとても役に立ちます。

{{Note|''zsh'' セッションを複数開いている場合、{{ic|cd}} しようとしても、両方のセッションによって同一のファイルに書き込む衝突が発生するため機能しません。}}

=== ヘルプコマンド ===
[[bash]] とは違って、''zsh'' は組み込まれている {{ic|help}} コマンドを有効にしていません。zsh で {{ic|help}} を使うには、以下を {{ic|zshrc}} に追加してください:

{{bc|1=
autoload -U run-help
autoload run-help-git
autoload run-help-svn
autoload run-help-svk
unalias run-help
alias help=run-help
}}

=== Fish のようなシンタックスハイライト ===

[[Fish]] には強力なシェルシンタックスハイライトがあります。これを zsh で使うには、公式リポジトリから {{pkg|zsh-syntax-highlighting}} をインストールして以下を zshrc に追加します:
{{bc|
source /usr/share/zsh/plugins/zsh-syntax-highlighting/zsh-syntax-highlighting.zsh
}}

=== サンプル .zshrc ファイル ===

以下は {{ic|.zshrc}} ファイルのリストです。自由に自分のファイルを追加してください:

* 公式リポジトリにある {{Pkg|grml-zsh-config}} パッケージは http://grml.org/zsh から取られて来たもので Zshell の多数の調整が含まれた zshrc ファイルが入っています。これは[https://www.archlinux.org/download/ 毎月リリースされている ISO] のデフォルト設定です。
* 動的なプロンプトとウィンドウタイトル、hardinfo を使う、基本セットアップ => http://github.com/MrElendig/dotfiles-alice/blob/master/.zshrc
* https://github.com/slashbeast/things/blob/master/configs/DOTzshrc - 複数の機能を有効にした zshrc、コメントを見て下さい。特徴: ユーザーが電源オフ・再起動・ハイバネートをすることを確認する関数、プロンプトの GIT サポート (vcsinfo を使わずに実現)、メニューの付いたタブ補完、実行中のコマンドをウィンドウのタイトルバーに表示など。

=== 設定フレームワーク ===

* [https://github.com/robbyrussell/oh-my-zsh oh-my-zsh] は Zsh の設定を管理するための、人気のあるコミュニティドリブンなフレームワークです。便利な関数、ヘルパー、プラグイン、テーマが山ほどバンドルされています。
* [https://github.com/sorin-ionescu/prezto Prezto - Instantly Awesome Zsh] (AUR の {{AUR|prezto-git}} でインストール可能) は Zsh の設定フレームワークです。デフォルトでリッチなコマンドラインインターフェース環境を構築するモジュール・エイリアス・関数・自動補完・プロンプトテーマが付いています。
* [https://github.com/zsh-users/antigen Antigen] (AUR の {{AUR|antigen-git}} でインストール可能) - zsh のプラグインマネージャ。oh-my-zsh と vundle の影響を受けています。

=== アプリケーションの自動起動 ===

Zsh はいつでも {{ic|/etc/zsh/zshenv}} と {{ic|$ZDOTDIR/.zshenv}} を実行します。なのでこれらのファイルをあまり肥大化させないでください。

シェルがログインシェルの場合、{{ic|/etc/profile}} そして {{ic|$ZDOTDIR/.zprofile}} からコマンドが読み込まれます。次に、シェルがインタラクティブの場合、{{ic|/etc/zsh/zshrc}} さらに {{ic|$ZDOTDIR/.zshrc}} からコマンドが読み込まれます。最後に、シェルがログインシェルの場合、{{ic|/etc/zsh/zlogin}} ついで {{ic|$ZDOTDIR/.zlogin}} が読み込まれます。

{{ic|man zsh}} の ''STARTUP/SHUTDOWN FILES'' セクションも参照してください。

== アンインストール ==

Zsh があなたに合わないと感じて Bash に戻りたいときは、Zsh パッケージを削除する前に必ず、まずデフォルトシェルを変更して下さい。

{{Warning|Failure to follow the below procedures will result in all kinds of problems: users will no longer have a working shell program.}}

ターミナルで次のコマンドを root で実行して下さい:
# chsh -s /bin/bash user
Zsh を使っている全てのユーザーで実行して下さい。

これで安全に Zsh パッケージを削除することができます。

以上を行わなかった場合、root で {{ic|/etc/passwd}} を編集することで Bash にデフォルトシェルを戻すことができます。

{{Warning|It is '''strongly''' recommended to use {{ic|vipw}} when editing user information as it prevents badly formatted entries.}}

例:

編集前:
''username'':x:1000:1000:Full Name,,,:/home/''username'':/bin/zsh
編集後:
''username'':x:1000:1000:Full Name,,,:/home/''username'':/bin/bash

== 参照 ==

*[http://zsh.sourceforge.net/Guide/zshguide.html ユーザーガイド]
*[http://zsh.sourceforge.net/Doc/Release/index-frame.html The Z Shell Manual] (different format available [http://zsh.sourceforge.net/Doc/ here])
*[http://zsh.sourceforge.net/FAQ/zshfaq01.html Zsh FAQ]
*[http://grml.org/zsh/zsh-lovers.html zsh-lovers(1)] (公式リポジトリの {{pkg|zsh-lovers}} で利用できます)
*[http://zshwiki.org/home/ Zsh Wiki]
*[https://wiki.gentoo.org/wiki/Zsh/HOWTO Gentoo Wiki: Zsh/HOWTO]
*[http://www.bash2zsh.com/zsh_refcard/refcard.pdf Bash2Zsh Reference Card]
*[http://www.pokerworld88.com/ Poker Online]
*[http://www.musimdomino.com/ Domino Online]
*[http://www.texaspoker83.com/ Texas Poker]
*[http://www.specialispoker.com/ Poker Online]
*[http://www.mejapoker88.com/ Poker Indonesia]
*[http://www.dinastipoker.com Agen Domino99]

ArchWiki - 利用者の投稿記録 [ja]

Zsh